
A Broadway producer for Apache Pulsar, built on top of pulsar-elixir.
Installation
Add :off_broadway_pulsar to your dependencies in mix.exs:
def deps do
  [
    {:off_broadway_pulsar, "~> 2.0.0"} <!-- x-release-please-version -->
  ]
end
Upgrading from 1.x? See Upgrading to 2.0 — 2.0 changes how the
connection is configured, renames the subscription type atoms and reshapes message metadata.
Quick Start
Supervise a Pulsar.Client alongside your pipeline — the producer attaches its consumers
to it, so the connection is shared by every producer stage and outlives any one of them:
children = [
  {Pulsar.Client, host: "pulsar://localhost:6650"},
  MyApp.PulsarPipeline
]
Then, assuming Pulsar is running on localhost:6650:
defmodule MyApp.PulsarPipeline do
  use Broadway

  def start_link(_opts) do
    Broadway.start_link(__MODULE__,
      name: __MODULE__,
      producer: [
        module: {OffBroadway.Pulsar.Producer,
          topics: ["persistent://public/default/my-topic"],
          subscription: "my-subscription"
        },
        concurrency: 1
      ],
      processors: [
        default: [concurrency: 10]
      ],
      batchers: [
        default: [
          batch_size: 100,
          batch_timeout: 1000
        ]
      ]
    )
  end

  @impl true
  def handle_message(_processor, message, _context) do
    IO.inspect(message.data, label: "Received")
    message
  end

  @impl true
  def handle_batch(_batcher, messages, _batch_info, _context) do
    IO.inspect(length(messages), label: "Batch size")
    messages
  end
end
The client defaults to :default. Name it to run more than one, or to consume from more
than one cluster, and select it with :client:
children = [
  {Pulsar.Client, name: :analytics, host: "pulsar://analytics:6650"},
  MyApp.AnalyticsPipeline
]

producer: [
  module: {OffBroadway.Pulsar.Producer,
    client: :analytics,
    topics: ["persistent://public/default/my-topic"],
    subscription: "my-subscription"
  },
  concurrency: 1
]
Configuration
:topics and :subscription are required. :client selects which running Pulsar.Client
to attach to, the :flow_* options tune read-ahead, :active_state_callback observes
failover transitions, and :consumer_opts is forwarded to Pulsar.Consumer.
Options are validated before any stage starts, so Broadway.start_link/2 itself raises on a
misconfigured pipeline rather than failing at the first message. The
producer documentation
lists every option with its type and default.
Flow control
:flow_initial permits are granted when each topic or partition consumer becomes ready. When
the remaining permits reach :flow_threshold, the producer adds :flow_refill permits. The
approximate maximum window per consumer is
max(flow_initial, flow_threshold + flow_refill); multiply it by the consumer count to
estimate total read-ahead.
Larger windows reduce refill overhead but increase buffered and unacknowledged messages.
Smaller windows may limit throughput. See the producer documentation above for the detailed
refill semantics.
Consumer options
:consumer_opts is forwarded to every consumer the stage starts.
Pulsar.Consumer documents and
validates the keys it accepts, and applies its own defaults to whatever is left out, so they
are deliberately not mirrored here.
The keys the producer sets for itself — the topic, subscription, callback module, consumer
count and flow settings — are rejected, each naming the option that does work instead: use
producer: [concurrency: N] for the consumer count, and the :flow_* options above for flow
control.
Failover active state
:active_state_callback is invoked as apply(module, function, [metadata | extra_args]),
where metadata carries the active state, the topic or partition, the subscription and the
consumer pid. It runs synchronously in the Pulsar consumer, so it should return promptly.
Reports are best-effort observations — they may repeat, and they are not a distributed lock
or fencing mechanism. The
producer documentation
has the complete callback contract.
Architecture
Back-pressure and buffering
Pulsar flow control and Broadway demand are separate budgets:
	Budget	Scope	Controls
	Pulsar permits	Each topic or partition consumer	Broker read-ahead into the producer buffer
	Broadway demand	Each producer stage	Dispatch from that buffer to processors

Each producer stage shares one Broadway demand counter and one message buffer across its
consumers. Messages delivered ahead of demand wait in that buffer. Permits are charged when
messages are dispatched, not when they are acknowledged.
Ownership and failure propagation
Broadway and pulsar-elixir have different lifecycle boundaries. The Pulsar.Client owns
shared connection infrastructure; each Broadway producer stage owns the consumers that feed
it. A consumer root therefore uses the client's infrastructure without being a child of the
client's consumer DynamicSupervisor.
flowchart TD
  APP[Application supervisor]
  CLIENT[Pulsar.Client]
  PIPELINE[Broadway pipeline]
  STAGE[Producer stage]
  ROOT[Consumer root<br/>one per topic]
  GROUP[Topic or partition group]
  WORKER[Consumer worker]
  REGISTRY[Consumer Registry]
  BROKER[Broker processes]

  APP --> CLIENT
  APP --> PIPELINE
  PIPELINE --> STAGE
  STAGE <-->|linked ownership| ROOT
  ROOT -->|supervises| GROUP
  GROUP -->|supervises| WORKER
  CLIENT --> REGISTRY
  CLIENT --> BROKER
  ROOT -. registers with .-> REGISTRY
  WORKER -. communicates with .-> BROKER
	Event	Result
	The producer stage exits	Its linked consumer roots stop
	A consumer root exits	Its link or monitor stops the stage; Broadway recreates it
	A retryable worker failure occurs	Pulsar's topology supervision restarts the worker
	A terminal subscription error stops a group	The stage's health check detects it and restarts
	The consumer Registry is replaced	Existing roots keep running by pid, but their former names no longer resolve
	A broker connection fails	The affected workers restart and reconnect through the client

Because the roots belong to their producer stages, Pulsar.Client.consumers/1 does not list
them. Stop the Broadway pipeline, rather than an individual root, to stop them permanently.
Message metadata
Each Broadway.Message carries its Pulsar origin and message fields in :metadata:
def handle_message(_processor, message, _context) do
  %{
    topic: topic,          # resolved topic; the concrete partition if partitioned
    base_topic: base,      # the configured topic
    partition: partition,  # partition index, or nil
    key: key,
    properties: properties
  } = message.metadata

  message
end
See the producer documentation
for the full list.
Examples
The examples/ directory contains self-contained, end-to-end scripts. With a local
Pulsar running (make up), run them with plain elixir:
	examples/atproto.exs — consumes the public AT Protocol feed over a websocket,
republishes every event to Pulsar, and computes live stream statistics (posting activity, languages, trending hashtags, most liked/reposted posts).

make up
elixir examples/atproto.exs



  

    Changelog

2.0.0 (2026-08-16)
⚠ BREAKING CHANGES
	reworked option handling (#86)
	upgrade to pulsar-elixir 3.x (#79)

Features
	stop asking for messages while draining (98fc392)
	upgrade to pulsar-elixir 3.x (#79) (10c0a34)

Bug Fixes
	do not crash the stage on an unexpected message (bc87cd9)
	survive loss of a consumer worker (#88) (4ba8a8f)
	tie consumer lifetime to the stage (#81) (eb93b72)

Performance Improvements
	use a queue for the producer message buffer (47e9ea6)

Dependencies
	bump styler from 1.11.0 to 1.12.1 (#74) (67381b4)
	bump styler from 1.12.1 to 1.12.2 (#76) (d5f0ed7)
	ci: bump jdx/mise-action from 4 to 4.2.3 (#77) (6ae4ff7)
	ci: bump jdx/mise-action from 4.2.3 to 4.2.4 (#78) (38488bc)
	ci: bump jdx/mise-action from 4.2.4 to 4.2.5 (#85) (103685b)
	docker: bump apachepulsar/pulsar from 4.0.2 to 4.2.4 (#84) (6543060)

Documentation
	add 1.x to 2.x upgrade guidelines (463e928)
	extend docs about manual flow control (#87) (4a367d2)
	publish the changelog with the generated docs (ae95286)

Code Refactoring
	reworked option handling (#86) (1de8748)
	validate option in prepare_for_start/2 (5fdd033)

Tests
	add batch-index ack test (99ca6a3)

Continuous Integration
	configure dependabot to bump docker-compose deps (7a2b532)

Miscellaneous Chores
	add configuration section to readme file (c98dc47)
	examples: add atproto e2e example (#82) (4c5842a)

1.5.1 (2026-07-20)
Dependencies
	bump pulsar from 2.11.0 to 2.11.1 (#72) (3a1a017)

1.5.0 (2026-07-19)
Features
	failover active state change callback (#70) (fcba675)

Dependencies
	bump pulsar from 2.10.1 to 2.11.0 (#69) (03b6e8a)
	bump pulsar from 2.9.0 to 2.10.1 (#67) (26e99ed)
	ci: bump actions/cache from 5 to 6 (#68) (8e3f33d)
	ci: bump actions/checkout from 6 to 7 (#65) (85e5949)

1.4.0 (2026-06-06)
Features
	pulsar: partition auto-discovery (54fb1b3)

Bug Fixes
	permit tracking is off for partitioned topics (9b297ad)

Dependencies
	bump erlang and elixir versions to 29 and 1.20 (#63) (ca4ad2c)
	bump pulsar from 2.8.17 to 2.9.0 (070859f)
	ci: bump actions/cache from 4 to 5 (#61) (7ca760f)
	ci: bump actions/checkout from 4 to 6 (#58) (ff23dd2)
	ci: bump dorny/test-reporter from 2.2.0 to 3.0.0 (#59) (fa55abd)
	ci: bump jdx/mise-action from 2 to 4 (#62) (63eb14d)

Continuous Integration
	bump version in readme on new release (#56) (3e98430)
	configure dependabot to bump gha dependencies (#57) (c44afb7)
	migrate releases to release-please (#54) (8b28f9a)

1.3.11 (2026-06-05)
1.3.10 (2026-05-23)
1.3.9 (2026-05-21)
1.3.8 (2026-05-21)
1.3.7 (2026-05-21)
1.3.6 (2026-05-08)
Bug Fixes
	inherit default callbacks for pulsar consumer (#48) (1b1e4fb)

1.3.5 (2026-03-22)
1.3.4 (2026-03-10)
1.3.3 (2026-03-05)
1.3.2 (2026-03-04)
1.3.1 (2026-02-28)
1.3.0 (2026-02-27)
Features
	add support for multi-topic producers (#39) (7e37e29)

1.2.11 (2026-02-27)
1.2.10 (2026-02-20)
1.2.9 (2026-02-04)
1.2.8 (2026-02-03)
1.2.7 (2026-01-29)
1.2.6 (2026-01-22)
1.2.5 (2026-01-22)
1.2.4 (2026-01-09)
1.2.3 (2025-12-27)
1.2.2 (2025-12-18)
1.2.1 (2025-12-15)
Bug Fixes
	missing chunking-related options (296d462)
	missing compaction-related settings (8868e05)

1.2.0 (2025-12-14)
Features
	add support for message chunking (29facd1)

1.1.0 (2025-12-06)
Features
	support pulsar-elixir multi-client architecture (93ba3fc)

1.0.4 (2025-12-05)
1.0.3 (2025-12-05)
1.0.2 (2025-12-05)
1.0.1 (2025-12-05)
1.0.0 (2025-12-05)
Features
	optional pulsar connection (0ebb96b)
	producer concurrency (d430692)
	support all pulsar-elixir options (454d20e)

Bug Fixes
	align demand handling with pulsar native flow control (f9ba1de)
	back pressure bug (40faa92)
	batched acknowledgements (a2a094e)
	dispatch message when pipeline waiting for demand (0484272)
	dispatch messages in order (d805b98)
	do not ignore startup delay and jitter (10097ec)
	do not start pulsar app automatically (ffb8c22)
	dynamic pulsar consumer process (a632b1e)
	only dispatch messages based on demand (81d34e9)
	pipeline stops on consumer restart (42e0324)
	stale consumer when using DLQ policy (da89a9d)
	wrong function clause in consumer (f2e1625)



  

    Upgrading to 2.0

2.0 moves to pulsar-elixir 3.x and reworks how
the producer is configured and how it owns its consumers. The configuration changes are
rejected at boot, so a pipeline that starts is configured correctly. The metadata change is
not: reading a key that moved raises on the first message instead.
Bump the dependency:
{:off_broadway_pulsar, "~> 2.0"}
At a glance
	1.x	2.0	Where
	:host + :conn_opts on the producer	Supervise Pulsar.Client yourself	Connections
	{Pulsar, host: ...} in your tree	{Pulsar.Client, host: ...}	Connections
	topic: "my-topic"	topics: ["my-topic"]	Topics
	subscription_type: :Shared	subscription_type: :shared	Subscription types
	Unknown :consumer_opts keys ignored	Unknown and reserved keys raise	Consumer options
	metadata.command, .metadata, …	Normalized fields, raw under :raw	Message metadata

Connections
The producer no longer starts or owns a connection. :host and :conn_opts are gone; the
client is yours to supervise, so the connection outlives any one producer stage and is shared
by all of them.
If you passed :host to the producer:
# 1.x
producer: [
  module: {OffBroadway.Pulsar.Producer,
    host: "pulsar://localhost:6650",
    conn_opts: [socket_opts: [verify: :verify_none]],
    topic: "my-topic",
    subscription: "my-subscription"
  }
]

# 2.0
children = [
  {Pulsar.Client, host: "pulsar://localhost:6650", socket_opts: [verify: :verify_none]},
  MyApp.PulsarPipeline
]

producer: [
  module: {OffBroadway.Pulsar.Producer,
    topics: ["my-topic"],
    subscription: "my-subscription"
  }
]
:conn_opts keys move up to Pulsar.Client itself — there is no nested option group any more.
If you were already running a global connection, the module name changed:
# 1.x
children = [{Pulsar, host: "pulsar://localhost:6650"}, MyApp.PulsarPipeline]

# 2.0
children = [{Pulsar.Client, host: "pulsar://localhost:6650"}, MyApp.PulsarPipeline]
Pulsar.Client registers as :default when unnamed, which is also the producer's default
:client, so an unnamed client needs no :client option. Name it to run more than one:
children = [
  {Pulsar.Client, name: :analytics, host: "pulsar://analytics:6650"},
  MyApp.AnalyticsPipeline
]

producer: [
  module: {OffBroadway.Pulsar.Producer,
    client: :analytics,
    topics: ["my-topic"],
    subscription: "my-subscription"
  }
]
A producer whose client is not running raises at boot with the supervision snippet it wants,
rather than failing to consume.
Topics
:topic is gone. Use :topics, always a non-empty list:
# 1.x
topic: "my-topic"

# 2.0
topics: ["my-topic"]
An empty list is rejected — it would leave a stage running with nothing to consume.
Subscription types
pulsar-elixir 3.x renamed the subscription type atoms to lowercase. This is the change most
likely to bite, because 1.x silently discarded a :consumer_opts key it did not recognise but
happily accepted a wrongly-cased value:
	1.x	2.0
	:Exclusive	:exclusive
	:Shared	:shared
	:Failover	:failover
	:Key_Shared	:key_shared

# 1.x
consumer_opts: [subscription_type: :Failover]

# 2.0
consumer_opts: [subscription_type: :failover]
:shared remains the default. Other option values — :initial_position, :start_message_id,
:dead_letter_policy and the rest — keep the shapes they had.
Consumer options
In 1.x, :consumer_opts was filtered through an allowlist with Keyword.take/2: anything the
producer did not recognise was dropped without a word, so subsciption_type: :Failover gave
you a Shared subscription in production. In 2.0 the keys are validated by Pulsar.Consumer,
which rejects what it does not know.
All fifteen consumer options 1.x supported still exist under the same names, so a correctly
spelled 1.x configuration carries over unchanged. A misspelled one now raises — which is the
point.
Two things to know:
Reserved keys raise. The producer sets some options itself, and setting them in
:consumer_opts would either be discarded or break its flow accounting. Each is rejected with
the option that does work instead:
:client, :topic, :subscription_name, :callback_module, :init_args, :name,
:consumer_count, :flow_policy, :flow_initial, :flow_threshold, :flow_refill
Use producer: [concurrency: N] for the consumer count, and the producer's own :flow_initial
/ :flow_threshold / :flow_refill for flow control.
Setting :consumer_opts replaces the default rather than merging into it. The default is
[subscription_type: :shared], which is also Pulsar.Consumer's own default, so in practice
nothing is lost — but spell out every option you want in a single list rather than expecting a
merge.
Message metadata
1.x exposed the wire protocol structs directly, which meant knowing that a batched message
carries its key in single_metadata while a non-batched one carries it in metadata. 2.0
gives you normalized fields that answer the same way regardless of how the message was
delivered, and keeps the protocol structs under :raw.
# 1.x
%{message_id: id, command: cmd, metadata: md, single_metadata: smd, broker_metadata: bmd} =
  message.metadata

# 2.0
%{command: cmd, metadata: md, single_metadata: smd, broker_metadata: bmd} = message.metadata.raw
:message_id keeps its name and its opaque role. The four protocol keys move under :raw.
Everything else is new:
:message_id_string, :topic, :base_topic, :partition, :subscription, :key,
:ordering_key, :properties, :producer_name, :publish_time, :event_time,
:redelivery_count
Prefer these over :raw, whose shape follows the wire protocol and is explicitly unstable.
Reading the key off a batched message, for instance, is now just message.metadata.key.
def handle_message(_processor, message, _context) do
  %{topic: topic, partition: partition, key: key, properties: properties} = message.metadata
  message
end
Behaviour changes that need no code change
These do not require edits, but they change what you will observe.
Consumer ownership. Each producer stage now starts and links its own consumer roots
instead of registering them under the client's DynamicSupervisor. A consumer that dies takes
its stage down and Broadway recreates both, where 1.x could leave a stage running with nothing
to consume. One consequence: Pulsar.Client.consumers/1 no longer lists a pipeline's
consumers. Stop the Broadway pipeline to stop them.
Acknowledgement failures no longer crash the pipeline. 1.x asserted :ok = Pulsar.ack(...),
so any ack failure raised inside Broadway's acknowledger and aborted the rest of that batch's
acknowledgements. 2.0 logs and continues.
Incomplete chunked and invalid messages are acknowledged and dropped. In 1.x an incomplete
chunked message was filtered out of the producer buffer but never acknowledged, so it held the
subscription's cursor. Both cases are now logged, acked and dropped before reaching the
pipeline.
Consumers subscribe immediately by default. pulsar-elixir 3.x defaults :startup_delay_ms
and :startup_jitter_ms to 0, where 2.x defaulted both to 1000. If you relied on that
stagger across a large fleet of restarting consumers, set them explicitly in :consumer_opts.
Worth checking while you are here
Neither of these changed in 2.0, but both are easy to get wrong and easy to fix during an
upgrade.
Broadway.Message.failed/2 does nothing without :redelivery_interval. A negative
acknowledgement is only redelivered when the consumer has a redelivery interval configured;
without one the message is not retried, and if it arrived in a batch its entry stays
unacknowledged until something acks it or the consumer restarts. If your pipeline marks
messages as failed and expects them back, set it:
consumer_opts: [subscription_type: :shared, redelivery_interval: 60_000]
Consider :batch_index_ack_enabled if your topics are batched. Pulsar producers batch by
default, and an acknowledgement names the entry it lands in, not the message. Broadway
routinely completes messages from one entry out of order and in different batches, so one
failed message causes its whole entry to be redelivered — and its already-successful siblings
to be processed a second time. Enabling batch index acknowledgement narrows redelivery to just
the messages that actually failed:
consumer_opts: [subscription_type: :shared, batch_index_ack_enabled: true]
It requires acknowledgmentAtBatchIndexLevelEnabled=true on the broker, which is the default
on Pulsar 4.2 — broker.conf sets it explicitly and a standalone broker inherits it, so a
cluster that has not overridden it already honours the setting. Check yours with
bin/pulsar-admin brokers get-all-dynamic-config, since nothing in the protocol reports it:
against a broker with it disabled, an ack acknowledges the whole entry and loses the messages
batched alongside it. It also costs one acknowledgement command per message rather than one
per entry.
Nacked messages come back only when :redelivery_interval is also set, so the two options go
together if you want a failed message retried rather than merely narrowed.
Complete example
# 1.x
defmodule MyApp.PulsarPipeline do
  use Broadway

  def start_link(_opts) do
    Broadway.start_link(__MODULE__,
      name: __MODULE__,
      producer: [
        module: {OffBroadway.Pulsar.Producer,
          host: "pulsar://localhost:6650",
          topic: "persistent://public/default/my-topic",
          subscription: "my-subscription",
          consumer_opts: [subscription_type: :Shared, initial_position: :earliest]
        },
        concurrency: 1
      ],
      processors: [default: [concurrency: 10]]
    )
  end

  @impl true
  def handle_message(_processor, message, _context) do
    key = message.metadata.single_metadata && message.metadata.single_metadata.partition_key
    IO.inspect({key, message.data})
    message
  end
end
# 2.0
children = [
  {Pulsar.Client, host: "pulsar://localhost:6650"},
  MyApp.PulsarPipeline
]

defmodule MyApp.PulsarPipeline do
  use Broadway

  def start_link(_opts) do
    Broadway.start_link(__MODULE__,
      name: __MODULE__,
      producer: [
        module: {OffBroadway.Pulsar.Producer,
          topics: ["persistent://public/default/my-topic"],
          subscription: "my-subscription",
          consumer_opts: [subscription_type: :shared, initial_position: :earliest]
        },
        concurrency: 1
      ],
      processors: [default: [concurrency: 10]]
    )
  end

  @impl true
  def handle_message(_processor, message, _context) do
    IO.inspect({message.metadata.key, message.data})
    message
  end
end
See the
producer documentation
for every option with its type and default.

A Broadway producer for Apache Pulsar.
This producer receives messages from Pulsar topics and forwards them to the
Broadway pipeline. It implements flow control using Pulsar's permit window
mechanism, which proactively requests batches of messages rather than
requesting per-message.
The connection belongs to your application: supervise a Pulsar.Client and this
producer attaches its consumers to it.
Each producer stage owns the consumers it starts. See "Consumer ownership" in
start_link/1.
See start_link/1 for detailed configuration options.

        Starts an OffBroadway.Pulsar producer process linked to the current
process.

Starts an OffBroadway.Pulsar producer process linked to the current
process.
Configuration
	:client (atom/0) - Name of the Pulsar.Client to attach to. The client must already be running; see
"Starting a client" below. The default value is :default.

	:topics - Required. The Pulsar topics to consume from, as a non-empty list of strings. One consumer is
started per topic.

	:subscription (String.t/0) - Required. The subscription name.

	:active_state_callback - A {module, function, extra_args} tuple that receives active/passive state changes for
Failover consumers. nil disables it. See "Failover Active State" below. The default value is nil.

	:consumer_opts (keyword/0) - Options forwarded to Pulsar.Consumer.start_link/1, applied to every topic. They are
documented and validated by Pulsar.Consumer, which rejects unknown keys and applies its
own defaults to whatever is left out — including subscription_type: :shared.
The keys the producer sets itself are rejected here: :client, :topic, :subscription_name, :callback_module, :init_args, :name, :consumer_count, :flow_policy, :flow_initial, :flow_threshold, :flow_refill. Use
producer: [concurrency: N] for the consumer count and the :flow_* options above for
flow control.
:batch_index_ack_enabled is worth enabling for Broadway, which routinely completes
messages from one batch out of order: without it a failed message takes its whole entry
back, and the siblings Broadway already handled are delivered again. It needs
acknowledgmentAtBatchIndexLevelEnabled on the broker, which is the Pulsar 4.2 default.
A nacked message is redelivered only when :redelivery_interval is set. Left unset, a
message the pipeline fails is not retried.
The default value is [subscription_type: :shared].

	:flow_initial (pos_integer/0) - Permits each consumer grants when it subscribes. The default value is 100.

	:flow_threshold (pos_integer/0) - Refill once outstanding permits reach this level. Must be less than :flow_initial. The default value is 50.

	:flow_refill (pos_integer/0) - Permits granted by each refill. The default value is 50.


Options are validated in Broadway.Producer.prepare_for_start/2, which runs before any
stage starts, so Broadway.start_link/2 raises the configuration error itself rather than
each stage crash-looping under its supervisor. They are validated again in
GenStage.init/1, which also covers starting this producer outside a Broadway pipeline.
The client is checked per stage instead, since a stage that restarts has to find it again.
Flow Control
Each topic or partition consumer has its own Pulsar permit window. Broadway demand and the
message buffer are shared by all consumers owned by one producer stage, so deliveries that
arrive ahead of demand wait in that buffer.
Each consumer grants :flow_initial permits when it subscribes. Permits are charged when
messages leave the buffer for the processors, not when they are acknowledged. When the
remaining permits reach :flow_threshold, the producer grants another :flow_refill permits.
The approximate maximum window per consumer is
max(flow_initial, flow_threshold + flow_refill). Account for every topic or partition
consumer and every producer stage when estimating total read-ahead. Larger windows reduce
refill overhead but increase buffered and unacknowledged messages; smaller windows may limit
throughput.
Consumer ownership
Each producer stage starts one linked consumer root per topic. Pulsar supervises the
partition groups and workers below each root; Broadway supervises the stage. A root exit
makes Broadway restart the stage and recreate all of its roots, while stopping the stage
stops its linked roots. Retryable worker failures remain local to the Pulsar topology.
Consumer roots use the client's broker infrastructure but are not children of its consumer
DynamicSupervisor. Consequently, Pulsar.Client.consumers/1 does not list them. The stage
owns them by pid, so replacing the client's consumer Registry does not affect them, although
their former names no longer resolve. Stop the Broadway pipeline to stop them permanently.
A terminal subscription error can leave a root alive with a stopped group, and a worker that
exits normally is not replaced, leaving a group alive with nothing consuming. The stage
detects both and restarts instead of remaining healthy with nothing to consume.
A worker that is replaced is not one of those cases. The replacement registers under a new
pid and the broker returns whatever the old worker left unacknowledged to it, so messages
still in the pipeline under the old pid are dropped when they come to be acknowledged.
Message Metadata
Each Broadway.Message carries the following :metadata:
	:message_id - Opaque id the acknowledger acks with. A list for a chunked message
	:message_id_string - The id as Pulsar prints it (ledgerId:entryId:partition, plus the
batch index when batched), for logging and correlation
	:topic - The resolved topic; the concrete partition for a partitioned topic
	:base_topic - The configured topic. Equal to :topic unless the topic is partitioned
	:partition - The partition index, or nil when the topic is not partitioned
	:subscription - The Pulsar subscription name
	:key - The partition key, or nil
	:ordering_key - The ordering key, or nil
	:properties - User properties, as a map
	:producer_name - The producer that published the message
	:publish_time - Broker publish timestamp, in milliseconds since the epoch
	:event_time - Application-set event time, or nil when unset
	:redelivery_count - How many times the broker has redelivered the message
	:raw - The underlying protocol structs, as a map of :command, :metadata,
:single_metadata and :broker_metadata. Its shape is unstable and follows the wire
protocol

These normalized fields are consistent for individual, batched and chunked messages.
Two kinds of message never reach the pipeline: an incomplete chunked message, whose
payload is a fragment, and one that failed validation. Both are logged, acknowledged
and dropped.
Failover Active State
Consumers using a :failover subscription report broker-provided active and
passive state changes through the optional :active_state_callback. Configure
the callback as a {module, function, extra_args} tuple. It is invoked as
apply(module, function, [metadata | extra_args]), where metadata contains:
	:active_state - Either :active or :passive
	:topic - The topic, or individual partition topic, whose state changed
	:subscription - The Pulsar subscription name
	:consumer_pid - The underlying Pulsar consumer process

The callback runs synchronously in the underlying Pulsar consumer and should
return promptly. Exceptions raised by the callback propagate and crash the
consumer. Reports are best-effort state observations: the same state may be
reported more than once, and consumer termination does not guarantee a final
:passive report. Treat reports idempotently and monitor :consumer_pid if
local work must stop when the consumer exits.
This signal is scoped to an individual topic or partition. It is not a
distributed lock or fencing mechanism, and it does not mean messages already
delivered to Broadway have finished processing.
With Broadway producer concurrency greater than one, multiple underlying
consumers can report different states for the same topic and subscription at
the same time. Track concurrent ownership observations by :consumer_pid, not
by topic alone.
Starting a client
Supervise the client above the pipeline, so the connection outlives any one producer
stage and is shared by all of them:
children = [
  {Pulsar.Client, host: "pulsar://localhost:6650"},
  MyApp.PulsarPipeline
]

producer: [
  module: {OffBroadway.Pulsar.Producer,
    topics: ["topic-a", "topic-b"],
    subscription: "my-subscription"
  }
]
Name the client to run more than one, or to consume from more than one cluster:
children = [
  {Pulsar.Client, name: :analytics, host: "pulsar://analytics:6650"},
  MyApp.AnalyticsPipeline
]

producer: [
  module: {OffBroadway.Pulsar.Producer,
    client: :analytics,
    topics: ["my-topic"],
    subscription: "my-subscription"
  }
]

